テーブル結合の解除

'http://gis.stackexchange.com/questions/11088/how-do-i-remove-a-join-between-a-standalone-table-and-a-feature-layer-with-arc
 
'VBA ヘルプにサンプルが記載
'Samples > Tables >
'How to remove all joins from a layer or table in ArcMap
Sub RemoveAllJoins()
 
  On Error GoTo EH
 
  Dim pMxDocument As IMxDocument
  Set pMxDocument = ThisDocument
   
  Dim pMap As IMap
  Set pMap = pMxDocument.FocusMap
   
  ' 選択レイヤー、もしくは テーブルを取得
  Dim pSelectedItem As IUnknown
  Set pSelectedItem = pMxDocument.SelectedItem
   
  If pSelectedItem Is Nothing Then
    MsgBox "コンテンツ ウィンドウで何も選択されていません。"
    Exit Sub
  End If
  If Not (TypeOf pSelectedItem Is ILayer Or TypeOf pSelectedItem Is IStandaloneTable) Then
    MsgBox "コンテンツ ウィンドウでフィーチャ レイヤ/テーブルが選択されていません。"
    Exit Sub
  End If
   
  Dim pDisplayRelationshipClass As IDisplayRelationshipClass
  Set pDisplayRelationshipClass = pSelectedItem
     
  ' すべての空間結合を削除
  If pDisplayRelationshipClass.RelationshipClass Is Nothing Then
    MsgBox "レイヤ/テーブルは結合されていません"
    Exit Sub
  End If
   
  Call pDisplayRelationshipClass.DisplayRelationshipClass(Nothing, esriLeftInnerJoin)
 
  Exit Sub
EH:
    
  MsgBox Err.Number & "  " & Err.Description
    
End Sub
 
 
'Samples > Tables >
'How to remove the last join from a layer or table in ArcMap